gd2 and serial data processing

[rayman]

i read data from serial and write to serial-logger, that works fine without gd2 display


#include <EEPROM.h>
#include <Wire.h>
#include <SPI.h>

#define SIN    Serial1
#define Logger Serial3
unsigned int OpenLogResetPin = 6;

void setup() {
   pinMode(OpenLogResetPin, OUTPUT);
   Serial.begin(115200);
   Logger.begin(38400);
   SIN.begin(19200, SERIAL_8N2);

   delay(100);
   LoggerInit();
}

void loop() {

   static boolean startByte;
   static int count;

   if ( SIN.available() ) {
       int inByte = SIN.read();
       if(startByte == false && inByte == 105) {
           startByte = true;
           count = 0;
           Logger.write(inByte); // write 105 to logger
       } else {
          Logger.write(inByte);
          count++;
          if(count == 124)
              startByte = false;
      }
   }
}

with gd i lose >90% serial data


#include <EEPROM.h>
#include <Wire.h>
#include <SPI.h>
#include <GD2.h>

#define SIN    Serial1
#define Logger Serial3
unsigned int OpenLogResetPin = 6;

void setup() {
   pinMode(OpenLogResetPin, OUTPUT);
   Serial.begin(115200);
   Logger.begin(38400);
   SIN.begin(19200, SERIAL_8N2);

   GD.begin();
   GD.ClearColorRGB(0xff0000);
   GD.Clear();
   GD.swap();

   delay(100);
   LoggerInit();
}

void loop() {
   GD.ClearColorRGB(0x0000ff);
   GD.Clear();
   GD.cmd_number(240, 136, 30, 10|OPT_CENTER, millis());
   GD.swap();

   static boolean startByte;
   static int count;

   if ( SIN.available() ) {
       int inByte = SIN.read();
       if(startByte == false && inByte == 105) {
           startByte = true;
           count = 0;
           Logger.write(inByte); // write 105 to logger
       } else {
          Logger.write(inByte);
          count++;
          if(count == 124)
              startByte = false;
      }
   }
}

i not understand the problem

[jamesbowman]

GD.swap() always waits for the next 60 Hz frame -- so this loop() function can never run faster than 60 Hz.

This means that this loop() can only handle 60 characters per second. One way of improving things is to change the 'if' to a 'while' here, so that each time loop() executes all the characters on SIN get copied:

   while ( SIN.available() ) {
       int inByte = SIN.read();
       if(startByte == false && inByte == 105) {
           startByte = true;
           count = 0;
           Logger.write(inByte); // write 105 to logger
       } else {
          Logger.write(inByte);
          count++;
          if(count == 124)
              startByte = false;
      }
   }
This may help.

[rayman]

thx for the info, i will redesign my sketch and test

... works fine

[rickyed]

Hello

jamesbowman, just one question .
we can remove this 16ms of standby ? may be modificate the code gd2 lib ?
because in my projet this standby in not requiered, but i can manage this timing of stand by with my code for make all work perfectly.

thank you for your answer

[jamesbowman]

Well, if you call GD.swap() slower than 60Hz, e.g. once every 100ms, then it does not block.

GD.swap() only blocks when it is called faster than 60Hz.

So if your code calls GD.swap() slower than once every 16.667 ms, it will not block or delay.

[rickyed]

thank you very much

excuse me, but i don't think at this.

thank !!!